~ start

if get_save_value("ambiQuestComplete", false):
	Ambrose: Meowdy!
	Ambrose: You can change the baskets out meow if you'd like.
	Ambrose: I just needed to see them in formation once :3
	Ambrose: Thank you myah.
	=> END

if not get_save_value("ambiQuestStarted", false):
	Ambrose: meoww could you help me set up the basket spots here?
	- sure => startQuest
	- sorry no => declineQuest

if not DialogueBoxManager.currentSpeaker.notes_check():
	Ambrose: Hi you uh need to find some of my notes still meow.
	if not DialogueBoxManager.currentSpeaker.note_check_1():
		Ambrose: I saw a page fly off towards the Snak Shak.
	if not DialogueBoxManager.currentSpeaker.note_check_2():
		Ambrose: I saw a page fly off towards the rocky island.
	if not DialogueBoxManager.currentSpeaker.note_check_3():
		Ambrose: I sensed that a page flew north and got stuck in a log.
	Ambrose: Good luck nyaa~
	=> END

~ checkRules
if not DialogueBoxManager.currentSpeaker.rules_check():
	Ambrose: Hi I think something's not right meow.
	if not DialogueBoxManager.currentSpeaker.basket_rule_check_1():
		Ambrose: ummm maybe look at note 1 again.
	if not DialogueBoxManager.currentSpeaker.basket_rule_check_2():
		Ambrose: myaa I think note 2 needs to be looked at.
	if not DialogueBoxManager.currentSpeaker.basket_rule_check_3():
		Ambrose: meowww note 3 is a tricky one, it doesn't feel like the baskets follow it well enough.
	Ambrose: Good luck nyaa~
	=> END
else:
	Ambrose: OwO it's perfect!!!
	Ambrose: Thank you so much!!!
	Ambrose: I will teach you my secret technique :3
	Ambrose: *Ambrose imbues you with a deep basketing secret*
	Ambrose: *You can now put an infinite amount of an item into a basket made from it*
	Ambrose: Have fun basketing meow!
	do set_save_value("ambiQuestComplete", true)
	do QuestManager.complete_quest("Constellation of Baskets")
	=> END

~ startQuest
if not LevelManager.skill_check("basketWeaving", 22) or not LevelManager.skill_check("scavenging", 15):
	Ambrose: mmmyahh I think you need a little more practice first though. (Requires level 22 Basket Weaving and level 15 Scavenging)
	=> END
Ambrose: Thank you! Here one moment I have some notes on how the baskets should be placed.
Ambrose: [Dexterity DC 3] Result: 1
Ambrose: *Ambrose fumbles with his pages and 3 of them fly off into the distance*
do set_save_value("ambiQuestStarted", true)
Ambrose: myaaaaaaahhhh oh no the pages all flew away!
Ambrose: I saw one fly off towards the Snak Shak.
Ambrose: And another go towards the rocky island.
Ambrose: [Perception DC 15] Result: 20
Ambrose: And I sense that a page flew north and got stuck in a log.
Ambrose: Please go get them and set up the baskets for me myah.
=> END

~ declineQuest
Ambrose: Ok let me know if you have time later nyah~

=> END